QT Creator 如何将第三方库加入到环境内 [复制链接]

例如：将boost库设置到QT Creator 环境变量内

供楼主参考.pro文件，需要注意的是，如果你用的编译器是MSVC，则不需要写要链接的boost库名，编译器会自动链接的，如果是GCC/MinGW，则需要手工写要链接的boost库名。

#####################################################################
# CTTransfer服务工程文件
# 编译器:   gcc/msvc
# 依赖库:   boost
#####################################################################
TEMPLATE = app
TARGET =
DESTDIR = ../../bin
DEPENDPATH += .
INCLUDEPATH += . ../include
#DEFINES += CHINUXTEAM_DEBUG
LIBS += -L../lib -L../../lib -lCTService
win32-msvc* {
    QMAKE_CXXFLAGS += -wd4100 -wd4503 -wd4819
    DEFINES += _WIN32_WINNT=0x0500 WIN32_LEAN_AND_MEAN _SCL_SECURE_NO_WARNINGS
    INCLUDEPATH += E:/Backup2/Boost/boost_1_40_0
    LIBS += -LE:/Backup2/Boost/boost_1_40_0/stage/lib -lole32 -ladvapi32
}
unix {
    QMAKE_CXXFLAGS += -fpermissive
    INCLUDEPATH += /mnt/hd/backup/boost_1_38_0/
    LIBS += -lpthread
    LIBS += -L/mnt/hd/backup/boost_1_38_0/stage/lib -lboost_system-gcc43-mt-s -lboost_thread-gcc43-mt-s -lboost_date_time-gcc43-mt-s -lboost_filesystem-gcc43-mt-s -lboost_program_options-gcc43-mt-s
}
CONFIG -= qt
CONFIG += release
win32:CONFIG += console

MOC_DIR = tmp
OBJECTS_DIR = tmp
UI_HEADERS_DIR = tmp

# Input
HEADERS += ViewSession.hpp \
           TransferSession.hpp \
           SaveSession.hpp \
           TransferServer.hpp
SOURCES += ViewSession.cpp \
           TransferSession.cpp \
           SaveSession.cpp \
           TransferServer.cpp \
           main.cpp

QT Creator 太痛苦了，版主有没有QT4.6.1编译好的windows版本SDK库。

我就是想将boost库将添加到QT Creator环境内，弄了半天还是不好使在build 环境内添加了include C:\boost_1_39_0 还是告诉我找不到xpressive.hpp文件，烦，这个项目还用到了libcurl等第三方库，

直接在pro文件中添加，没用什么麻烦的。