QextSerialPort输出自动在Target后加入数字？[已解决] [复制链接]

从网上下了qextserialport的源码编译，src.pro如下：
PROJECT = qextserialport
TEMPLATE = lib
VERSION = 1.2.0
DESTDIR = build
CONFIG += qt warn_on debug_and_release
CONFIG += dll
DEFINES += QEXTSERIALPORT_LIB
#CONFIG += staticlib

# event driven device enumeration on windows requires the gui module
!win32:QT -= gui

OBJECTS_DIR = tmp
MOC_DIR = tmp
DEPENDDIR = .
INCLUDEDIR = .
HEADERS = qextserialport.h \
qextserialenumerator.h \
qextserialport_global.h
SOURCES = qextserialport.cpp

unix:SOURCES += posix_qextserialport.cpp
unix:!macx:SOURCES += qextserialenumerator_unix.cpp
macx {
SOURCES += qextserialenumerator_osx.cpp
LIBS += -framework IOKit -framework CoreFoundation
}

win32 {
SOURCES += win_qextserialport.cpp qextserialenumerator_win.cpp
DEFINES += WINVER=0x0501 # needed for mingw to pull in appropriate dbt business...probably a better way to do this
LIBS += -lsetupapi
}


CONFIG(debug, debug|release) {
TARGET = qextserialportd
} else {
TARGET = qextserialport
}

上面已经指定了输出的名称，使用qmake生成的makefile中的TARGET自动在上面给出的文件名后加了数字1
这是不是qt的一个bug，有人遇到过吗？

==================================================================================

奇怪了，自己写的dll生成又是正常的，看来是qextserialport的问题
不知道还有哪里可以控制工程的输出，除了pro里的TARGET?

==================================================================================

搞定，注掉VERSION = 1.2.0
参见http://code.google.com/p/qextserialport/issues/detail?id=62